提供: Japanese Scratch-Wiki

このきじは ひらがなのページがありません。ごめんなさい。編集者向け:作成する
() と言う
[Hello!] と言う
カテゴリ 見た目
タイプ スタック

() と言うブロック見た目ブロックスタックブロック)は、現在のスプライトに指定したテキストを入れたふきだしを表示するブロックである。このふきだしは、別の「言う」/「考える」ブロックが実行されるか、または、ストップボタンが押されるまで表示される。表示されるふきだしの種類の違いを除けば、このブロックと() と考えるブロックは、まったく同じ動作をする(「() と言う」のふきだしは声に出した言葉を表し、「() と考える」のふきだしは声に出さない言葉を表す)。

なお、このブロックを実行したあとは、すぐさま次のブロックが実行される。この点が() と () 秒言うブロックと異なる。

使用例

Scratchキャット が「() と言う」ブロックで「Hello!」

このブロックは、消そうとしないと消えないふきだしを表示するので(ふきだしを消す方法は、よくある間違いを参照)、いつ終わるかわからない処理(ユーザーの操作を待っているときなど)を待ってふきだしを消したいときによく使用される。 よくある例は次のとおり:

  • ずっと鳴いている状態を表現
[ブーンブーン] と言う
  • ずっと表示しておきたい絵やサインなど
[<-- Dragon  {}  Bank -->] と言う
  • 消えないメッセージ
[永遠に消えないサインだよ] と言う 
  • スペースキーが押されたときに次のメッセージに切り替える場合
@greenFlag が押されたとき::events hat
[生命、宇宙、そして万物についての究極の疑問の答えを知りたいかい? (スペースキーを押す)] と言う
< [スペース v] キーが押された> まで待つ
[42] と言う

※参照 生命、宇宙、そして万物についての究極の疑問の答え

  • 「あなたの勝ちです!」「ご意見、ご感想をコメントしてください」など、プロジェクトの最後に表示するメッセージ
@greenFlag が押されたとき::events hat
<(スコア) > (9)> まで待つ
[すばらしい!10点です。あなたの勝ちです!] と言う
  • 見ている人にメッセージの表示時間を選ばせる場合
@greenFlag が押されたとき::events hat
[どのくらいの時間、πの値を言ってればいいですか?] と聞いて待つ
[3.14159265358979323846264338327950288...] と言う
(答え) 秒待つ
[] と言う
  • そのメッセージが必要な間だけ表示する場合
@greenFlag が押されたとき::events hat
[続けるには、スペースキーを押してください] と言う
< [スペース v] キーが押された> まで待つ
[続ける v] を送る
[] と言う

よくある間違い

「() と言う」ブロック の動作について、スクリプトが終了したときや次のブロックに処理が移動したとき、メッセージが消えると勘違いされていることがあるが、これは間違いである。そのスプライトが別の内容を「言う」か「考える」まで、メッセージは消えない。スプライトのふきだしを消すには、テキストを空にしたメッセージをしゃべらせる必要がある。

Warning メモ: ただし、プロジェクト を開始/終了したときは、すべてのふきだしが消える。

次に、ふきだしでメッセージを表示し、いつ終わるか事前にはわからない処理が終わったタイミングでメッセージを消す例を示す:

@greenFlag が押されたとき::events hat
[回るから見てて!] と言う
((90) から (110) までの乱数) 回繰り返す
@turnRight (4) 度回す
end
say []

デバッグでの利用

「() と言う」ブロックはプロジェクトをデバッグするときに役立つ。たとえば、変数の値がどのように変動するか見たいときは、「ずっと」のループの中に、その変数を指定した「() と言う」ブロックを入れておけばよい。 次に例を示す:

ずっと
((var1) + ((var2) * (var3))) と言う
end

関連項目