() 回繰り返す (ブロック)

このきじはひらがなでよめます。ひらがなでよむ

() 回繰り返すブロック（制御ブロック／C型ブロック）は、指定した回数、中に入っているブロックをくり返し実行する（ループする）ブロックである。くり返しが終わったあとは、このブロックの下にあるスクリプトが実行される。

回数として小数を入力すると、四捨五入される。

このブロックの実行時にはちょっぴり遅延が発生するので、実行速度を優先したいときは、シングルフレームブロックスタックを使用すべきである。

使用例

同じコードを何度も繰り返し実行できるので、時間とスペースの節約のためによく使われる。よくある使用例は次のとおり：

(10) 回繰り返す
	[変数 v] を (1) ずつ変える
	次のコスチュームにする
	もし <[カベ v]に触れた?> なら
		全部消す::pen
		[リロード v]を送る
	でなければ
		スタンプ
	end
end

アニメーション — コスチュームの変更と動作のタイミングをひとつずつ全部プログラムする代わりに、() 回繰り返すブロック(と次のコスチュームにするブロック)を使用すれば、コードの量をだいぶ減らせる。

(8) 回繰り返す
	(0.05) 秒待つ
	次のコスチュームにする
end

(20) 回繰り返す
	y座標を (3) ずつ変える
	もし<[端 v] に触れた> なら
		[色 v] の効果を (75) ずつ変える
	end
end

() 回繰り返すブロックの中に、さらに別の() 回繰り返すブロックを置くこともできる。これは「入れ子」（ネスト）と呼ばれる。この場合、繰り返し回数の合計は、２つの() 回繰り返すブロックに指定した回数をかけあわせた数になる。たとえば次の場合は、入れ子の繰り返しによって10個の点を10回ペンで描くので、全部で100個の点が描かれる。

ペンの太さを (2) にする
x座標を (-100) 、y座標を (100) にする
(10) 回繰り返す
	(10) 回繰り返す
		ペンを下ろす
		ペンを上げる
		x座標を (20) ずつ変える
	end
	x座標を (-100) ずつ変える
	y座標を (-20) ずつ変える
end

詳細は「代用ブロック一覧」を参照

このブロックの動作は、次のようにブロックを組んだ場合と同じである：

[カウンター v] を(0)にする
<(カウンター) = (繰り返し回数)>まで繰り返す
...
[カウンター v] を(1)ずつ変える